COMMENT ⊗   VALID 00004 PAGES
C REC  PAGE   DESCRIPTION
C00001 00001
C00002 00002	% This file contains punctuation marks common to roman and italic styles.
C00003 00003	cmchar "Left parenthesis"
C00004 00004	cmchar "Right parenthesis"
C00005 ENDMK
C⊗;
% This file contains punctuation marks common to roman and italic styles.
% Codes \¬041, \¬043, \¬045, \¬047--\¬054, \¬056, \¬057, \¬072, \¬073, \¬075,
% \¬100, \¬133, \¬135, and \¬140 are used.
% A Spanish exclamation point is also generated, with code \\{spanx},
% unless $\\{spanx}<0$.
cmchar "Left parenthesis";
numeric dp#; .5[body_height#,-dp#]=math_axis#;
beginchar("(",7u# if monospace: -u# fi,body_height#,dp#);
italcorr body_height#*slant-.5u#;
adjust_fit(0,0);
pickup fine_pen;
penpos1(tiny-fine,0); penpos3(tiny-fine,0);
penpos2(.75[hair,stem]-fine,0);
rt x1r = rt x3r = w-u; lft x2l = x1-4u if monospace: +4/3u fi;
top y1=h; y2=.5[y1,y3]=math_axis;
filldraw z1l{curl 4}..z2l..{curl 4}z3l--
	  z3r{curl 4}..z2r..{curl 4}z1r--cycle; % the stroke
labels.top(3,2);
labels.bot(1);
labels.lft(1l,2l,3l);
labels.rt(1r,2r,3r);
endchar;
cmchar "Right parenthesis";
numeric dp#; .5[body_height#,-dp#]=math_axis#;
beginchar(")",7u# if monospace: -u# fi,body_height#,dp#);
italcorr math_axis#*slant-.5u#;
adjust_fit(0,0);
pickup fine_pen;
penpos1(tiny-fine,0); penpos3(tiny-fine,0);
penpos2(.75[hair,stem]-fine,0);
lft x1l = lft x3l = u; rt x2r = x1+4u if monospace: -4/3u fi;
top y1=h; y2=.5[y1,y3]=math_axis;
filldraw z1l{curl 4}..z2l..{curl 4}z3l--
	  z3r{curl 4}..z2r..{curl 4}z1r--cycle; % the stroke
labels.top(3,2);
labels.bot(1);
labels.lft(1l,2l,3l);
labels.rt(1r,2r,3r);
endchar;